Selur's Little Message Board

Full Version: 1-CLICK FIX for broken DGDecNV.ini + DGDec.ini of DGDecNV + DGDec @ Hybrid
You're currently viewing a stripped down version of our content. View the full version with proper formatting.
Hi,

Since I had the problem, that DGDecNV / DGDec didn't work at Hybrid anymore, I wrote a small 1-Click FIX tool "FIX_HYBRID_DGIndex" to fix the problem with broken / missing .ini files version and folder structure independet (DG adds the current version number of DGDecNV.exe / DGDec.exe at the top of his ini files).
All DGDecNV.ini files and DGDec.ini files that are needed for Hybrid will be replaced / recreated!
So if somebody has a problem with error messages regarding to .ini files, like this:
Quote:---------------------------
Fehler
---------------------------
'Default save project path' in the INI file is invalid.
Defaulting to empty.
---------------------------
OK 
---------------------------
Or encoding always crashes at your joblist, try this fix to replace / recreate all missing ini files in your Hybrid folder.
Simply copy this code into a textfile, rename it to FIX_HYBRID_DGIndex_1.0.BAT and start it with admin rights (right click->start as admin / with admin rights or similar):
Code:
@echo off
chcp 1252 >nul
:START
echo -------------------------------------------------------------------------------
echo.
echo FIX_HYBRID_DGIndex_1.0 (2022.06.12) for broken DGIndex(NV) ini files at Hybrid
echo                DGIndexNV + DGIndex VERSION INDEPENDENT fix!
echo.
echo -------------------------------------------------------------------------------
echo.
echo I will create a DGIndex.ini / DGINdexNV.ini in every subfolder of your Hybrid
echo folder, where DGIndex.exe / DGIndexNV.exe is found. So it's independent from
echo your folder structure.
echo Version number of found DGIndex.exe or DGIndexNV.exe is added to ini file!
echo.
echo Script needs to be started with admin rights, or it will fail!!!
echo (right click-^>start as admin / with admin rights or similar)
echo.
echo Copy 'n paste you Hybrid folder (drag 'n drop doesn't work in admin mode).
set /p "hybridFolder="
echo.
REM Method to remove quotation marks, if they're inserted unexpectedly in admin mode
setlocal enabledelayedexpansion
set hybridFolder=!hybridFolder:"=!
endlocal & set "hybridFolder=%hybridFolder%"

if not exist "%hybridFolder%\Hybrid.exe" echo Hybrid.exe not found in this folder & goto :START

call :MAKE_VER_VBS
for /f "delims=" %%a in ('dir /b /s "%hybridFolder%\DGIndex.exe"') do (call :FIX_DGINDEX "%%~da" "%%~pa" "%%~na" "%%~xa")
for /f "delims=" %%a in ('dir /b /s "%hybridFolder%\DGIndexNV.exe"') do (call :FIX_DGINDEXNV "%%~da" "%%~pa" "%%~na" "%%~xa")
del /f /q "%tmp%\getVerDGIx.vbs"
echo.
echo all done...
PAUSE & EXIT


:FIX_DGINDEX
if exist "%~1%~2DGIndex.ini" del /f /q "%~1%~2DGIndex.ini" >nul
if exist "%~1%~2DGIndex.ini" (echo Problem deleting old ini file "%~1%~2DGIndex.ini", admin rights? & PAUSE & EXIT)

set "fileVer="
for /f "tokens=1 delims=" %%a in ('cscript //nologo "%tmp%\getVerDGIx.vbs" "%~1%~2%~3%~4"') do (echo setting DGIndex.exe fileversion '%%a' in new DGIndex .ini file! & set "fileVer=%%a")
echo Writing "%~1%~2DGIndex.ini"...
echo DGIndex_fileVer=DGIndex %fileVer%>"%~1%~2DGIndex.ini"
if not exist "%~1%~2DGIndex.ini" (echo Problem writing new ini file "%~1%~2DGIndex.ini", admin rights? & PAUSE & EXIT)

echo Window_Position=100,10^0>>"%~1%~2DGIndex.ini"
echo Info_Window_Position=100,10^0>>"%~1%~2DGIndex.ini"
echo iDCT_Algorithm=^6>>"%~1%~2DGIndex.ini"
echo YUVRGB_Scale=^1>>"%~1%~2DGIndex.ini"
echo Field_Operation=^0>>"%~1%~2DGIndex.ini"
echo Output_Method=^2>>"%~1%~2DGIndex.ini"
echo Track_List=>>"%~1%~2DGIndex.ini"
echo DR_Control=^2>>"%~1%~2DGIndex.ini"
echo DS_Downmix=^0>>"%~1%~2DGIndex.ini"
echo SRC_Precision=^0>>"%~1%~2DGIndex.ini"
echo Norm_Ratio=10^0>>"%~1%~2DGIndex.ini"
echo Process_Priority=^2>>"%~1%~2DGIndex.ini"
echo Playback_Speed=^3>>"%~1%~2DGIndex.ini"
echo Force_Open_Gops=^0>>"%~1%~2DGIndex.ini"
echo AVS_Template_Path=>>"%~1%~2DGIndex.ini"
echo Full_Path_In_Files=^1>>"%~1%~2DGIndex.ini"
echo Fusion_Audio=^0>>"%~1%~2DGIndex.ini"
echo Loop_Playback=^0>>"%~1%~2DGIndex.ini"
echo HD_Display=^1>>"%~1%~2DGIndex.ini"
echo MRUList[0]=>>"%~1%~2DGIndex.ini"
echo MRUList[1]=>>"%~1%~2DGIndex.ini"
echo MRUList[2]=>>"%~1%~2DGIndex.ini"
echo MRUList[3]=>>"%~1%~2DGIndex.ini"
echo Enable_Info_Log=^1>>"%~1%~2DGIndex.ini"
echo BMP_Path=>>"%~1%~2DGIndex.ini"
echo Use_MPA_Extensions=^0>>"%~1%~2DGIndex.ini"
echo Notify_When_Done=^0>>"%~1%~2DGIndex.ini"
goto :EOF


:FIX_DGINDEXNV
if exist "%~1%~2DGIndexNV.ini" del /f /q "%~1%~2DGIndexNV.ini" >nul
if exist "%~1%~2DGIndexNV.ini" (echo Problem deleting old ini file "%~1%~2DGIndexNV.ini", admin rights? & PAUSE & EXIT)

set "fileVer="
for /f "tokens=1 delims=" %%a in ('cscript //nologo "%tmp%\getVerDGIx.vbs" "%~1%~2%~3%~4"') do (echo setting DGIndexNV.exe fileversion '%%a' in new DGIndexNV .ini file! & set "fileVer=%%a")
echo Writing "%~1%~2DGIndexNV.ini"...
echo DGIndex_fileVer=DGIndex %fileVer%>"%~1%~2DGIndexNV.ini"
if not exist "%~1%~2DGIndexNV.ini" (echo Problem writing new ini file "%~1%~2DGIndexNV.ini", admin rights? & PAUSE & EXIT)

echo fileVer=DGIndexNV %fileVer%>"%~1%~2DGIndexNV.ini"
echo Window_Position=0,^0>>"%~1%~2DGIndexNV.ini"
echo Info_Window_Position=0,^0>>"%~1%~2DGIndexNV.ini"
echo Process_Priority=^2>>"%~1%~2DGIndexNV.ini"
echo Playback_Speed=^0>>"%~1%~2DGIndexNV.ini"
echo AVS_Template_Folder=>>"%~1%~2DGIndexNV.ini"
echo AVS_Template_File=>>"%~1%~2DGIndexNV.ini"
echo AVS_Template_File_Index=^0>>"%~1%~2DGIndexNV.ini"
echo AVS_Enable_Template=^0>>"%~1%~2DGIndexNV.ini"
echo AVS_Overwrite=^0>>"%~1%~2DGIndexNV.ini"
echo Full_Path_In_Files=^0>>"%~1%~2DGIndexNV.ini"
echo MRUList[0]=>>"%~1%~2DGIndexNV.ini"
echo MRUList[1]=>>"%~1%~2DGIndexNV.ini"
echo MRUList[2]=>>"%~1%~2DGIndexNV.ini"
echo MRUList[3]=>>"%~1%~2DGIndexNV.ini"
echo Enable_Info_Log=^0>>"%~1%~2DGIndexNV.ini"
echo Loop_Playback=^0>>"%~1%~2DGIndexNV.ini"
echo AVC_Extension=26^4>>"%~1%~2DGIndexNV.ini"
echo MPG_Extension=m2v>>"%~1%~2DGIndexNV.ini"
echo VC1_Extension=vc^1>>"%~1%~2DGIndexNV.ini"
echo HEVC_Extension=hevc>>"%~1%~2DGIndexNV.ini"
echo Deinterlace=^0>>"%~1%~2DGIndexNV.ini"
echo UsePF=^0>>"%~1%~2DGIndexNV.ini"
echo UseD3D=^0>>"%~1%~2DGIndexNV.ini"
echo Snapped=^0>>"%~1%~2DGIndexNV.ini"
echo ResponseOnAudioMismatch=^0>>"%~1%~2DGIndexNV.ini"
echo Enable_Demux=^0>>"%~1%~2DGIndexNV.ini"
echo CUDA_Device=^0>>"%~1%~2DGIndexNV.ini"
echo Decode_Modes=0,0,0,^0>>"%~1%~2DGIndexNV.ini"
echo Full_Info=^1>>"%~1%~2DGIndexNV.ini"
echo Bare_Demux=^0>>"%~1%~2DGIndexNV.ini"
echo Disable_Encrypted_Audio_Warning=^0>>"%~1%~2DGIndexNV.ini"
echo Force_Zoom=^0>>"%~1%~2DGIndexNV.ini"
echo StrictAVC=^0>>"%~1%~2DGIndexNV.ini"
echo PGSForcedOnly=^0>>"%~1%~2DGIndexNV.ini"
echo Default_Save_Project_Path=>>"%~1%~2DGIndexNV.ini"
echo H2S_Settings=0,0,0,0,0.00,0.00,0.000000,0.00,0.00,0.0^0>>"%~1%~2DGIndexNV.ini"
echo Generate_THD_AC3=^0>>"%~1%~2DGIndexNV.ini"
echo Optimize_For_HDD=^0>>"%~1%~2DGIndexNV.ini"
echo Preview_Path=>>"%~1%~2DGIndexNV.ini"
echo Save_Chapters_As_Xml=^0>>"%~1%~2DGIndexNV.ini"
echo Languages=>>"%~1%~2DGIndexNV.ini"
echo MKVExtract_Path=>>"%~1%~2DGIndexNV.ini"
goto :EOF


:MAKE_VER_VBS
set "fileVer="
echo Set objWMIService=GetObject("winmgmts:{impersonationLevel=impersonate}!\\.\root\cimv2")>"%tmp%\getVerDGIx.vbs"
echo Set colFiles=objWMIService.ExecQuery ("SELECT * FROM CIM_Datafile WHERE Name='"^&Replace(WScript.Arguments(0),"\","\\")^&"'")>>"%tmp%\getVerDGIx.vbs"
echo For Each objFile in colFiles: WScript.Echo objFile.Version: Next>>"%tmp%\getVerDGIx.vbs"
goto :EOF
Have fun Big Grin